<xsl:function name="tei:isFirstlevel-heading" as="xs:boolean">
  <xsl:param name="p"/>
  <xsl:choose>
    <xsl:when test="matches($p/w:pPr/w:pStyle/@w:val,'[Hh]eading[ ]?1')">true</xsl:when>
    <xsl:otherwise>false</xsl:otherwise>
  </xsl:choose>
</xsl:function>

<xsl:function name="tei:is-heading" as="xs:boolean">
  <xsl:param name="p"/>
  <xsl:variable name="s" select="$p/w:pPr/w:pStyle/@w:val"/>
  <xsl:choose>
    <xsl:when test="matches($s,'[Hh]eading.+')">true</xsl:when>
    <xsl:when test="matches($s,'[Cc]aption')">true</xsl:when>
    <xsl:when test="matches($s,'Figure[ ]?title')">true</xsl:when>
    <xsl:otherwise>false</xsl:otherwise>
  </xsl:choose>
</xsl:function>

<xsl:function name="tei:is-front" as="xs:boolean">
  <xsl:param name="p"/>
  <xsl:variable name="s" select="$p/w:pPr/w:pStyle/@w:val"/>
  <xsl:choose>
    <xsl:when test="matches($s,'[Tt]itle.*')">true</xsl:when>
    <xsl:when test="matches($s,'[Ss]ubtitle.*')">true</xsl:when>
    <xsl:when test="matches($s,'[Dd]ate.*')">true</xsl:when>
    <xsl:when test="matches($s,'[Aa]uthor.*')">true</xsl:when>
    <xsl:otherwise>false</xsl:otherwise>
  </xsl:choose>
</xsl:function>

<xsl:function name="tei:is-list" as="xs:boolean">
  <xsl:param name="p"/>
  <xsl:variable name="style" select="$p/w:pPr/w:pStyle/@w:val"/>
  <xsl:variable name="stylePr" select="document($styleDoc)//w:style[w:name/@w:val=$style]"/>
  <xsl:choose>
    <xsl:when test="$p/w:pPr/w:pStyle/@w:val='dl'">true</xsl:when>
    <xsl:when test="$p/w:pPr/w:numPr/w:ilvl">true</xsl:when>
    <xsl:when test="contains($style,'List') and $p/w:pPr/w:numPr[not(w:ins)]">true</xsl:when>
    <xsl:when test="contains($style,'List') and $stylePr/w:pPr/w:numPr[not(w:ins)]">true</xsl:when>
    <xsl:otherwise>false</xsl:otherwise>
  </xsl:choose>
</xsl:function>

<xsl:function name="tei:is-toc" as="xs:boolean">
  <xsl:param name="p"/>
  <xsl:choose>
    <xsl:when test="$p[contains(w:pPr/w:pStyle/@w:val,'toc')]">true</xsl:when>
    <xsl:when test="$p[contains(w:pPr/w:pStyle/@w:val,'TOC')]">true</xsl:when>
    <xsl:otherwise>false</xsl:otherwise>
  </xsl:choose>
</xsl:function>

<xsl:function name="tei:is-figure" as="xs:boolean">
  <xsl:param name="p"/>
  <xsl:choose>
    <xsl:when test="$p[matches(w:pPr/w:pStyle/@w:val,'[Ff]igure')]">true</xsl:when>
    <xsl:when test="$p[w:r/w:drawing and not(w:r/w:t)]">true</xsl:when>
    <xsl:otherwise>false</xsl:otherwise>
  </xsl:choose>
</xsl:function>

<xsl:function name="tei:is-caption" as="xs:boolean">
  <xsl:param name="p"/>
  <xsl:choose>
    <xsl:when test="$p[matches(w:pPr/w:pStyle/@w:val,'[Cc]aption')]">true</xsl:when>
    <xsl:when test="$p[matches(w:pPr/w:pStyle/@w:val,'Figuretitle')]">true</xsl:when>
    <xsl:otherwise>false</xsl:otherwise>
  </xsl:choose>
</xsl:function>

<xsl:function name="tei:is-line" as="xs:boolean">
  <xsl:param name="p"/>
  <xsl:choose>
    <xsl:when test="$p[w:pPr/w:pStyle/@w:val='tei_l']">true</xsl:when>
    <xsl:otherwise>false</xsl:otherwise>
  </xsl:choose>
</xsl:function>

<xsl:function name="tei:is-glosslist" as="xs:boolean">
  <xsl:param name="p"/>
  <xsl:choose>
    <xsl:when test="$p[w:pPr/w:pStyle/@w:val='dl']">true</xsl:when>
    <xsl:otherwise>false</xsl:otherwise>
  </xsl:choose>
</xsl:function>

<xsl:function name="tei:get-nextlevel-header" as="xs:string">
  <xsl:param name="current-header"/>
  <xsl:value-of select="translate($current-header,'12345678','23456789')"/>
</xsl:function>

<xsl:function name="tei:get-listtype" as="xs:string">
  <xsl:param name="style"/>
  <xsl:choose>
    <xsl:when test="starts-with($style,'dl')">
      <xsl:text>gloss</xsl:text>
    </xsl:when>
    <xsl:when test="starts-with($style,$ListBullet)">
      <xsl:text>bulleted</xsl:text>
    </xsl:when>
    <xsl:when test="starts-with($style,$ListContinue)">
      <xsl:text>bulleted</xsl:text>
    </xsl:when>
    <xsl:when test="starts-with($style,$ListNumber)">
      <xsl:text>numbered</xsl:text>
    </xsl:when>
    <xsl:when test="$style=$List">
      <xsl:text>numbered</xsl:text>
    </xsl:when>
    <xsl:otherwise>
      <xsl:text/>
    </xsl:otherwise>
  </xsl:choose>
</xsl:function>

<xsl:function name="tei:docxError" as="node()+">
  <xsl:param name="message"/>
  <hi xmlns="http://www.tei-c.org/ns/1.0" style="color:red; font-size: 14pt; font-weight:bold;" rend="ERROR">�</hi>
  <note place="margin" type="conversion" resp="#docxtotei" xmlns="http://www.tei-c.org/ns/1.0">
    <hi rend="docxError">
      <xsl:value-of select="$message"/>
    </hi>
  </note>
  <xsl:message>docx conversion issue:
    <xsl:value-of select="$message"/>
  </xsl:message>
</xsl:function>

<xsl:function name="tei:processInstruction" as="xs:string">
  <xsl:param name="instr"/>
  <xsl:variable name="instr">
    <xsl:value-of select="replace($instr, '^\s+|\s+$', '')"/>
  </xsl:variable>
  <xsl:choose>
    <xsl:when test="matches($instr, 'REF _')">
      <!-- this will also catch NOTEREF _ -->
      <xsl:value-of select="concat('#', substring-before(substring-after($instr, '_'), ' '))"/>
    </xsl:when>
    <xsl:when test="matches($instr, 'HYPERLINK \\l ')">
      <xsl:variable name="target">
        <xsl:value-of select="translate(tokenize($instr, ' ')[3], $dq, '')"/>
      </xsl:variable>
      <xsl:value-of select="             if (matches($target, '^_')) then               concat('#', substring($target, 2))             else               $target"/>
    </xsl:when>
    <xsl:when test="matches($instr, 'HYPERLINK')">
      <xsl:variable name="target">
        <xsl:value-of select="translate(tokenize($instr, ' ')[2], $dq, '')"/>
      </xsl:variable>
      <xsl:value-of select="             if (matches($target, '^_')) then               concat('#', substring($target, 2))             else               $target"/>
    </xsl:when>
    <xsl:otherwise>
      <xsl:value-of select="             if (matches($instr, '(^|#)_')) then               replace($instr, '(^|#)_', '#')             else               $instr"/>
    </xsl:otherwise>
  </xsl:choose>
</xsl:function>

<xsl:function name="tei:discardInstruction" as="xs:boolean">
  <xsl:param name="instr"/>
  <xsl:choose>
    <xsl:when test="contains($instr,'REF _')">true</xsl:when>
    <xsl:when test="matches($instr,'^[ ]?QUOTE')">true</xsl:when>
    <xsl:when test="matches($instr,'^[ ]?XE')">true</xsl:when>
    <xsl:when test="contains($instr,'SEQ')">true</xsl:when>
    <xsl:when test="contains($instr,'FORMTEXT')">true</xsl:when>
    <xsl:otherwise>false</xsl:otherwise>
  </xsl:choose>
</xsl:function>

<xsl:function name="tei:biblioInstruction" as="xs:boolean">
  <xsl:param name="instr"/>
  <xsl:choose>
    <xsl:when test="matches($instr,'^[ ]?EN.REFLIST')">true</xsl:when>
    <xsl:when test="matches($instr,'^[ ]?ADDIN')">true</xsl:when>
    <xsl:when test="matches($instr,'^[ ]?ref Mendeley Edited')">true</xsl:when>
    <xsl:otherwise>false</xsl:otherwise>
  </xsl:choose>
</xsl:function>

<xsl:function name="tei:onOff" as="xs:boolean">
  <xsl:param name="e"/>
  <xsl:choose>
    <xsl:when test="exists($e)">
      <xsl:variable name="val" select="$e/@w:val"/>
      <xsl:choose>
        <xsl:when test="not(exists($val))">
          <xsl:sequence select="true()"/>
        </xsl:when>
        <xsl:when test="$val = 'true'">
          <xsl:sequence select="true()"/>
        </xsl:when>
        <xsl:when test="$val = 'on'">
          <xsl:sequence select="true()"/>
        </xsl:when>
        <xsl:when test="$val = '1'">
          <xsl:sequence select="true()"/>
        </xsl:when>
        <xsl:when test="$val = 'false'">
          <xsl:sequence select="false()"/>
        </xsl:when>
        <xsl:when test="$val = 'none'">
          <xsl:sequence select="false()"/>
        </xsl:when>
        <xsl:when test="$val = 'off'">
          <xsl:sequence select="false()"/>
        </xsl:when>
        <xsl:when test="$val = '0'">
          <xsl:sequence select="false()"/>
        </xsl:when>
        <xsl:otherwise>
          <xsl:sequence select="false()"/>
        </xsl:otherwise>
      </xsl:choose>
    </xsl:when>
    <xsl:otherwise>
      <xsl:sequence select="false()"/>
    </xsl:otherwise>
  </xsl:choose>
</xsl:function>

<xsl:function name="tei:justification" as="xs:string">
  <xsl:param name="jc"/>
  <xsl:choose>
    <xsl:when test="$jc/@w:val='start'">left</xsl:when>
    <xsl:when test="$jc/@w:val='end'">right</xsl:when>
    <xsl:when test="$jc/@w:val='left'">left</xsl:when>
    <xsl:when test="$jc/@w:val='right'">right</xsl:when>
    <xsl:when test="$jc/@w:val='center'">center</xsl:when>
    <xsl:when test="$jc/@w:val='both'">justify</xsl:when>
    <xsl:otherwise>left</xsl:otherwise>
  </xsl:choose>
</xsl:function>